Đánh giá lequocthai.com:
Hàm MONTH thuộc nhóm hàm Ngày/Giờ trong Excel, dùng để tách lấy phần tháng từ một ngày hợp lệ. Hàm sẽ trả về một số nguyên từ 1 đến 12. Kết quả này có thể được sử dụng làm đầu vào cho một hàm khác thông qua việc lồng ghép hàm MONTH.
Cú pháp
Cú pháp của hàm MONTH như sau:
=MONTH(serial_number)Đối số:
‘
serial_number
‘ – Đây là đối số bắt buộc, nơi bạn cần cung cấp số sê-ri của ngày hoặc tham chiếu đến ô chứa ngày mà bạn muốn lấy tháng.
Đặc điểm quan trọng của hàm MONTH
Hàm MONTH luôn trả về một số nguyên từ 1 (tháng Một) đến 12 (tháng Mười Hai).
Ô chứa kết quả có thể được định dạng để hiển thị tên tháng thay vì số.
Ngày trong đối số serial_number có thể được cung cấp dưới dạng: số sê-ri, một chuỗi văn bản ngày hợp lệ (ví dụ: “25-Dec-2001”), kết quả từ hàm DATE, hoặc kết quả từ hàm
TODAY
.
Ví dụ
Hãy cùng xem xét một số ví dụ về hàm MONTH.
Ví dụ 1 – Công Thức Cơ Bản Của Hàm MONTH
Chúng ta sẽ bắt đầu với công thức cơ bản nhất. Lấy một ngày và dùng hàm MONTH để tách lấy tháng của ngày đó, như sau:
=MONTH(A2)
Như minh họa, chúng ta cũng nhận được kết quả tương tự với các công thức sau:
=MONTH("25-Dec-2001")=MONTH(DATE(2001, 12, 25))Với ngày 25 tháng 12 năm 2001 được cung cấp làm đối số
serial_number
, công thức trả về 12. Đây là một hàm đơn giản luôn trả về giá trị số nguyên. Bây giờ, hãy cùng ứng dụng nó vào những tình huống thú vị hơn.
Ví dụ 2 – Làm Nổi Bật Các Ngày Trong Tháng Hiện Tại
Giả sử chúng ta có một danh sách ngày giao dịch ngân hàng khá dài và không theo thứ tự. Để dễ dàng đối chiếu giao dịch trong một tháng cụ thể, chúng ta có thể yêu cầu Excel tự động làm nổi bật các ngày thuộc tháng đó.
Chúng ta sẽ sử dụng công thức sau cho Định dạng Có điều kiện:
=MONTH(A2) = MONTH(TODAY())
Chọn vùng dữ liệu chứa ngày, tạo một
Quy tắc Mới (New Rule)
từ phần
Kiểu (Styles)
trong tab
Trang chủ (Home)
. Định dạng các ô với màu nền xanh lá cây hoặc màu tùy chọn. Kết quả sẽ hiển thị như hình trên.
Công thức này kiểm tra xem tháng của ngày trong ô A2 có trùng với tháng của ngày hôm nay (từ hàm TODAY) hay không. Nếu muốn kiểm tra với một tháng khác, bạn chỉ cần thay hàm TODAY bằng một ngày bất kỳ thuộc tháng đó.
Công thức trả về giá trị TRUE/FALSE. Nếu hai tháng trùng khớp, công thức trả về TRUE và ô được tô màu. Ngược lại, nó trả về FALSE và ô không được định dạng.
Ví dụ 3 – Kiểm Tra Một Năm Có Phải Năm Nhuận Không
Sau khi nắm vững kiến thức cơ bản, hãy chuyển sang một công thức phức tạp hơn một chút: xác minh xem một năm có phải là năm nhuận không. Chúng ta sẽ kết hợp hàm MONTH, DATE và
hàm YEAR
.
Công thức như sau:
=MONTH((DATE(YEAR(A2),2,29)))=2
Công thức trông có vẻ rườm rà vì chứa ba hàm, nhưng logic lại khá đơn giản.
Hàm YEAR lấy năm từ ô A2 (ví dụ: 1999) và truyền vào hàm
DATE
. Hàm DATE sẽ cố gắng tạo ngày 29 tháng 2 của năm đó.
Tuy nhiên, ngày 29 tháng 2 năm 1999 không phải là ngày hợp lệ. Do đó, Excel sẽ tự động chuyển nó thành ngày đầu tiên của tháng tiếp theo, tức là 1 tháng 3 năm 1999.
Đến đây, hẳn bạn đã hiểu cách công thức hoạt động. Nếu năm đó có ngày 29/2 (năm nhuận), hàm MONTH sẽ nhận được ngày 29/2 và trả về 2 (tháng Hai). Nếu không phải năm nhuận, hàm MONTH sẽ nhận ngày 1/3 và trả về 3 (tháng Ba). Công thức kiểm tra xem kết quả của hàm MONTH có bằng 2 không. Nếu có, nó trả về TRUE (là năm nhuận), ngược lại trả về FALSE.
Ví dụ 4 – Chuyển Tên Tháng Thành Số
Bây giờ, chúng ta sẽ chuyển đổi một danh sách tên tháng thành số tương ứng (ví dụ: January thành 1, February thành 2…). Chúng ta sử dụng hàm MONTH kết hợp với hàm DATEVALUE:
=MONTH(DATEVALUE(A2&"1"))
Nếu bạn đã biết toán tử & dùng để nối chuỗi, bạn sẽ hiểu ngay mục đích của công thức này. Với những bạn chưa rõ, chúng ta sẽ phân tích từng bước.
Hàm
DATEVALUE
chuyển một chuỗi văn bản thành một ngày hợp lệ. Ở đây, chúng ta nối tên tháng (January, February…) với số “1” (việc mà ký hiệu & thực hiện). Vậy, chuỗi cung cấp cho DATEVALUE sẽ là “January 1”, “February 1”,…
Lưu ý rằng chúng ta chưa thêm năm. Điều này không cần thiết vì hàm DATEVALUE sẽ mặc định sử dụng năm hiện tại. Ví dụ, nó sẽ trả về ngày “1/1/2021”.
Công việc của hàm MONTH vẫn không thay đổi: nhận một ngày hợp lệ (“1/1/2021”) và trích xuất ra tháng của nó, trả về số 1.
Ví dụ 5 – Xác Định Quý Tài Chính Từ Một Ngày
Giả sử chúng ta có một danh sách ngày và muốn biết chúng thuộc quý nào của một năm tài chính cụ thể. Tuy không có hàm sẵn cho việc này, chúng ta chỉ cần hiểu về
hàm CHOOSE
và vận dụng một chút logic.
=CHOOSE(MONTH(A2),4,4,4,1,1,1,2,2,2,3,3,3)
Đối số đầu tiên của hàm CHOOSE là một số chỉ mục, quyết định giá trị nào trong các đối số sau sẽ được trả về. Ví dụ, nếu số chỉ mục là 4, hàm sẽ trả về giá trị thứ tư được liệt kê, tức là 1.
Trong công thức này, kết quả từ hàm MONTH (từ 1 đến 12) đóng vai trò số chỉ mục đó.
Ví dụ này giả định năm tài chính bắt đầu từ tháng Tư (quý 1: T4-T6) và kết thúc vào tháng Ba năm sau (quý 4: T1-T3). Do đó, ba số 4 đầu tiên tương ứng với ba tháng đầu năm dương lịch (T1, T2, T3) thuộc về quý 4 của năm tài chính. Nếu bạn muốn năm tài chính bắt đầu từ tháng Mười, bạn sẽ cần điều chỉnh lại chuỗi số này cho phù hợp.
Như vậy, chúng ta đã thảo luận về mọi khía cạnh của hàm MONTH. Đây là một hàm đơn giản nhưng cực kỳ hữu ích khi làm việc với dữ liệu ngày tháng trong Excel. Hãy thực hành các công thức trên, chúng sẽ sớm trở thành phản xạ tự nhiên của bạn. Khi đã thành thạo, hãy cùng chúng tôi khám phá những hàm Excel hữu ích khác.
