Hàm CHOOSECOLS trong Excel – Cách Sử Dụng

Bằng cách sử dụng hàm CHOOSECOLS, bạn có thể tinh giản quy trình phân tích dữ liệu và tiết kiệm thời gian quý báu trong công việc với Excel.

Cú pháp

Cú pháp của hàm CHOOSECOLS rất đơn giản và như sau.

=CHOOSECOLS(array,col_num1,[col_num2],…)

Đối số:

Hàm CHOOSECOLS nhận một mảng và một hoặc nhiều số cột làm đối số. Chi tiết về mỗi đối số được nêu dưới đây để bạn dễ hiểu hơn.

• array: Đối số bắt buộc, là mảng gốc từ đó chúng ta muốn trích xuất các cột cụ thể.
• col_num1: Đối số bắt buộc, là số của cột đầu tiên muốn trích xuất từ mảng gốc.
• col_num2: Từ đối số này trở đi là các đối số tùy chọn, đại diện cho số của các cột bổ sung muốn trích xuất.

Giá trị của các đối số col_num có thể là số dương hoặc số âm. Số dương chỉ ra rằng cột sẽ được lấy từ phía trái của mảng, trong khi số âm chỉ ra rằng cột sẽ được lấy từ phía phải của mảng.

Nếu muốn trích xuất nhiều cột, bạn có thể liệt kê các số cột dưới dạng các đối số riêng biệt, hoặc dùng một đối số duy nhất dưới dạng hằng số mảng, trong đó liệt kê các số cột cần lấy.

Đặc điểm quan trọng của hàm CHOOSECOLS

• Mảng kết quả trả về bởi hàm CHOOSECOLS sẽ có cùng số dòng với mảng gốc, nhưng chỉ chứa các cột đã chọn.
• Hàm CHOOSECOLS sẽ tràn (spill) kết quả vào các dòng và cột tương ứng.
• Các số cột trong đối số col_num phải là số nguyên và phải tương ứng với vị trí cột hợp lệ trong mảng gốc.
• Nếu bất kỳ giá trị nào của các đối số col_num có giá trị bằng 0 hoặc vượt quá số cột của mảng, Excel sẽ trả về lỗi #VALUE.

Ví dụ về hàm CHOOSECOLS

Hãy bắt đầu bằng việc hiểu chức năng cơ bản của hàm CHOOSECOLS. Ở đây chúng ta có một bộ dữ liệu đơn giản gồm các số ngẫu nhiên trong ba cột. Chúng ta muốn trích xuất cột 1 và cột 3 từ mảng lớn hơn.

Công thức sẽ như sau.

=CHOOSECOLS(B2:D5,1,3)

Công thức lấy phạm vi B2:D5 làm đối số đầu tiên, đại diện cho toàn bộ bộ dữ liệu. Đối số thứ hai, “1” chỉ cột đầu tiên của bộ dữ liệu (tức là cột B) trong khi đối số thứ ba, “3”, chỉ cột thứ ba (tức là cột D). Vì vậy, kết quả của công thức là một mảng hoặc phạm vi mới chỉ bao gồm dữ liệu từ các cột B và D của bộ dữ liệu gốc, các cột còn lại bị loại bỏ.

Bây giờ chức năng cơ bản đã rõ, chúng ta sẽ chuyển sang các ứng dụng và ví dụ thực tế.

Ví dụ 1 – Trích xuất hai cột bằng hàm CHOOSECOLS

Trong ví dụ này, chúng ta có một bộ dữ liệu chứa thông tin về doanh số bán hàng của công ty trong năm qua. Bộ dữ liệu bao gồm các cột: tên nhân viên bán hàng, ngày bán, sản phẩm bán, số lượng bán và tổng doanh số.

Để thực hiện phân tích nhanh, chúng ta muốn tạo một báo cáo tóm tắt hiển thị tổng doanh số cho mỗi nhân viên.

Để tạo báo cáo tóm tắt, chúng ta chỉ cần các cột B và F. Công thức sẽ như sau.

=CHOOSECOLS(B2:F10,1,5)

Một ứng dụng đơn giản của hàm CHOOSECOLS cho phép chúng ta lọc dữ liệu theo nhu cầu.

Ví dụ 2 – Trích xuất cột cuối cùng bằng hàm CHOOSECOLS

Trong ví dụ này, chúng ta đã tải về giá cổ phiếu hàng ngày của một công ty muốn đầu tư từ internet. Để phân tích, chúng ta muốn lấy dữ liệu của tháng cuối cùng để tính giá trung bình của tháng đó.

Chúng ta có thể dùng CHOOSECOLS để trích xuất các cột B và H chứa dữ liệu của tháng cuối cùng cùng với ngày. Một cách làm là đếm tổng số cột thủ công rồi dùng số cột đầu và cuối làm giá trị cho đối số col_num. Công thức sẽ như sau.

=CHOOSECOLS(B2:H12,1,7)

Nếu có bộ dữ liệu lớn, việc đếm số cột sẽ không còn hiệu quả. Thay vào đó, chúng ta có thể dùng giá trị âm cho col_num để hàm CHOOSECOLS đếm từ phải sang trái. Công thức cập nhật như sau.

=CHOOSECOLS(B2:H12,1,-1)

Bây giờ bạn có thể tính trung bình giá một cách dễ dàng.

Ví dụ 3 – Đảo ngược thứ tự cột bằng hàm CHOOSECOLS

Trong ví dụ này, chúng ta có một bộ dữ liệu chứa số liệu doanh thu hàng tháng của công ty trong 5 năm qua, và muốn phân tích xu hướng doanh thu theo thời gian. Dữ liệu được sắp xếp theo cột, mỗi cột đại diện cho một năm, mỗi hàng đại diện cho một tháng.

Để phân tích hiệu quả hơn, chúng ta muốn hiển thị dữ liệu mới nhất trước và đảo ngược thứ tự các cột.

Bằng cách kết hợp CHOOSECOLS với các hàm Excel khác, chúng ta có thể lật mảng doanh thu hàng tháng để các cột được sắp xếp ngược lại, tức là từ năm mới nhất tới năm cũ nhất.

Chúng ta sẽ dùng hàm SEQUENCE để tạo dãy số xác định thứ tự các cột cho đối số col_num của CHOOSECOLS. Để đảo ngược, chúng ta nhân mỗi số trong dãy với -1.

Đầu tiên, dùng hàm COLUMNS để đếm tổng số cột trong phạm vi.

=COLUMNS(B2:G7)

Tiếp theo, dùng SEQUENCE để tạo dãy số từ 1 đến số cột vừa đếm.

=SEQUENCE(COLUMNS(B2:G7))

Sau đó nhân dãy này với -1 để đảo ngược.

=SEQUENCE(COLUMNS(B2:G7)) * -1

Cuối cùng, công thức hoàn chỉnh:

=CHOOSECOLS(B2:G7, SEQUENCE(COLUMNS(B2:G7)) * -1)

Việc đảo ngược dữ liệu sẽ giúp phân tích xu hướng dễ dàng hơn.

Ví dụ 4 – Trích xuất các cột dựa trên chuỗi ký tự có số

Giả sử chúng ta có một cơ sở dữ liệu đơn đặt hàng của khách hàng, bao gồm các cột: tên khách hàng, số đơn hàng, ngày đặt, tổng tiền và số lượng. Người dùng có thể nhập các số cột muốn trích xuất ở ô C1 dưới dạng chuỗi, ví dụ “1,2,5”.

Đầu tiên, cần tách chuỗi này thành một mảng các số bằng hàm TEXTSPLIT, sau đó chuyển mảng đó cho CHOOSECOLS.

=TEXTSPLIT(C1,",")*1

Chúng ta nhân kết quả với 1 để chuyển định dạng văn bản sang số.

Sau khi có các số cột, dùng chúng làm đối số col_num:

=CHOOSECOLS(B3:F13,TEXTSPLIT(C1,",")*1)

Bây giờ bất kỳ người dùng nào cũng có thể trích xuất các cột mong muốn.

Ví dụ 5 – Trích xuất các cột từ nhiều vùng dữ liệu bằng CHOOSECOLS

Giả sử bạn làm việc cho một công ty bán hàng và có dữ liệu bán hàng cho từng nhân viên ở ba khu vực: Bắc, Nam và Tây. Dữ liệu của mỗi khu vực được lưu trong các phạm vi riêng biệt.

Chúng ta muốn tạo báo cáo tổng hợp doanh số tháng 1 cho mỗi nhân viên ở ba khu vực. Đầu tiên, dùng hàm VSTACK để ghép ba phạm vi lại thành một bảng duy nhất, rồi dùng CHOOSECOLS để lấy các cột 1 và 2.

=VSTACK(B3:E6,B10:E12,B16:E18)

Sau khi ghép, áp dụng CHOOSECOLS:

=CHOOSECOLS(VSTACK(B3:E6,B10:E12,B16:E18),1,2)

CHOOSECOLS vs CHOOSEROWS

Hàm CHOOSECOLS trả về một mảng mới chỉ chứa các cột đã chọn, trong khi hàm CHOOSEROWS trả về một phạm vi mới chỉ chứa các hàng đã chọn.

Sự khác biệt chính nằm ở cách chúng xử lý đối số: CHOOSECOLS nhận các số cột, CHOOSEROWS nhận các số hàng.

Ví dụ, với một mảng số ngẫu nhiên 5 hàng 5 cột:

Để lấy hàng 2 và 5, dùng:

=CHOOSEROWS(A1:E5,2,5)

Kết quả là dữ liệu của các hàng 2 và 5.

Để lấy cột 2 và 5, dùng:

=CHOOSECOLS(A1:E5,2,5)

Như vậy, tùy thuộc vào việc bạn muốn chọn cột hay hàng, hãy sử dụng CHOOSECOLS hoặc CHOOSEROWS.

Hãy thực hành và khám phá các cách mới để sử dụng hàm CHOOSECOLS; chúng tôi sẽ giới thiệu thêm các hàm Excel hữu ích khác.